VBScript9

１３．４　閉合トラバース 　　　　　　　　　[もくじへ] [トップページへ] [前ページへ]

===================================================

プログラム例題２５

閉合トラバースのプログラムを作成せよ。

=========================================================

考え方

観測データには、いろいろな原因による誤差が含まれます。したがって、それ

から求められた方向角や座標には当然誤差を生じます。閉合トラバースが開

放トラバースと違う点は、この誤差を補正するか、補正しないかという点です。

閉合トラバースでは、方向角の誤差と、座標の誤差の２つに分けて処理します。

（１）方向角の誤差（閉合差）の処理

開放トラバースと同じように、点ｎまで方向角を計算します。

　　　α₁ = α_A + β₁ 　　　　　（ α₁ が３６０°を超えたら３６０°を減ずる　）

　　　α_n-1 = α_n-2 + β_n-1 + 180°（ α_n が３６０°を超えたら３６０°を減ずる　）

閉合トラバースでは、さらに初点（点ｎ）に戻り、 β_n を測定します。

そして、

　　　α_n = α_n-1 + β_n + 180°

により、 α_n を求め、α_Aとの閉合差 ω を求めます。ω を測角数 n で除し

て各観測角に補正します。

もし閉合差が整除できない場合、つぎのように補正します。

　　　　　　　　ω = 9″を n = 7 で配布する場合

　　　　　　　　ω/n ≒ 1.3″

　　　　　　　　累加補正数　　　　　各角への補正数

　　　　　　　　　1.3 ≒ 1　　　　　　　　　　　　 = 1″　　　　

　　　　　　　　　2.6 ≒ 3　　　　　　　　　3 - 1 = 2″

　　　　　　　　　3.9 ≒ 4　　　　　　　　　4 - 3 = 1″

　　　　　　　　　5.2 ≒ 5　　　　　　　　　5 - 4 = 1″

　　　　　　　　　6.5 ≒ 7　　　　　　　　　7 - 5 = 2″

　　　　　　　　　7.8 ≒ 8　　　　　　　　　8 - 7 = 1″

　　　　　　　　　9.1 ≒ 9　　　　　　　　　9 - 8 = 1″

このようにして、観測角の補正をしたあと、ふたたび方向角の計算をやり直し

ます。

（２）座標の誤差（閉合差）の処理

方向角の補正計算の後、各点の座標を次式により計算します。

　　　X_i = X_i-1 + S_icos(α_i)

　　　Y_i = Y_i-1 + S_isin(α_i)

最後の測点の座標と、初点座標との座標閉合差を求めます。

　　　E_x= X_n-1 - X_A

　　　Ey = Y_n-1 - Y_A

この座標閉合差を、各測線長（観測距離）に比例して配布します。

　　　Ｘ座標に対する補正数 = E_x× S_i /ΣS

　　　Y座標に対する補正数 = E_y × S_i /ΣS

この場合の端数は、最後の点に配布します。

このような、座標に対する閉合差の配布法をコンパス法といいます。

閉合差 ds は、

で求められます。

また、精度　h は、

　　　 h = ds / ΣS

で求められます。

プログラム

<HTML>
<HEAD>
　　　<TITLE>例題２５</TITLE>

<SCRIPT LANGUAGE="VBScript">

</SCRIPT>

</HEAD>

<BODY>

<FORM NAME="Form1">
　＊＊＊　トラバース計算　＊＊＊<BR>
<BR>
初点名= <INPUT TYPE="text" NAME="AN" size=15>
　　 XA= <INPUT TYPE="text" NAME="XA" size=15>
　　 YA= <INPUT TYPE="text" NAME="YA" size=15>
　　αA= <INPUT TYPE="text" NAME="AA" size=15>
<BR>
終点名= <INPUT TYPE="text" NAME="BN" size=15>
　　 XB= <INPUT TYPE="text" NAME="XB" size=15>
　　 YB= <INPUT TYPE="text" NAME="YB" size=15>
　　αB= <INPUT TYPE="text" NAME="AB" size=15>
<BR>
　番号= <INPUT TYPE="text" NAME="NO" size=15>
　点名= <INPUT TYPE="text" NAME="NA" size=15>
　測角= <INPUT TYPE="text" NAME="BT" size=15>
　距離= <INPUT TYPE="text" NAME="DS" size=15>
<BR>
<BR>
　　　　　 <INPUT TYPE="button" NAME="BCK" VALUE="　＜　">
<INPUT TYPE="button" NAME="FRD" VALUE="　＞　">
　　　　　 <INPUT TYPE="button" NAME="INI" VALUE="クリア">
<INPUT TYPE="button" NAME="CAL" VALUE="計　算">
<HR>

</FORM>

</BODY>
</HTML>

入力データと実行結果

　　　　　　　　Ｘ_A=100.00m,　Ｙ_A=100.00m,　α_A=300°0′0″
　　　　　　　　点名=1,　β₁=180°0′ 0″,　　　S₁=100.00m
　　　　　　　　点名=2,　β₂= 60°0′ 0″,　　　S₂=100.00m
　　　　　　　　点名=A,　β₃= 60°0′ 0″,　　　S₃=100.00m
　　　　　　　　点名=B,　β₄=240°0′20″

　　　　　※４点目の入力は、点名=　Ｂ、夾角=　240.0020、距離=　なし

　　　　　※必ずクリアボタンをクリックしてから入力します。

　　　　　※入力終了は、点名にＥを入力して、計算ボタンをクリックします。

プログラムの説明

        Dim w                                                        '測角誤差
        Dim et(50)                                               '夾角への補正数
        Dim sex, sey                                           'X、Y座標誤差
        Dim delts, ss                                           '閉合差、距離合計
        Dim ex(50), ey(50)                                'X、Y座標への補正数
        Dim seido                                                 '精度

開放トラバースのプログラムに、追加したグローバル変数です。計算結果出

力のプロシージャ Heigo でも使うので、グローバル変数にします。

        Sub CAL_OnClick
                Dim i, r
                Dim ew, sg                             '測角誤差w/n、その符号　　①
                Dim exs, eys                         'X、Ｙの累加補正数　　②
'
                '初点データ
                an = document.Form1.AN.value
                xa = CDbl(document.Form1.XA.value)
                ya = CDbl(document.Form1.YA.value)
                alpa = CDbl(document.Form1.AA.value)
'
                '終点データ
                bn = document.Form1.BN.value
                xb = CDbl(document.Form1.XB.value)
                yb = CDbl(document.Form1.YB.value)
                alpb = CDbl(document.Form1.AB.value)
'
                '測点データ
                na(ii) = document.Form1.NA.value
                bt(ii) = CDbl(document.Form1.BT.value)
                ds(ii) = CDbl(document.Form1.DS.value)
'
                '測点数のカウント
                n = 0
                For i = 1 To 50
                        If na(i)="E" Then Exit For
                             n = n + 1
                Next
'
'
'　　　＊＊＊　計算部　＊＊＊
' 　　角度を秒に変換
                alpa = Dobyo(alpa)
                For i = 1 To n
                        bt(i) = Dobyo(bt(i))
                Next
'
                ai(1) = alpa + bt(1)
                Do While ai(1)>=1296000
                      ai(1) = ai(1) - 1296000
                Loop
                For i = 2 To n
                        ai(i) = ai(i-1) + bt(i) + 648000
                        Do While ai(i)>=1296000
                              ai(i) = ai(i) - 1296000
                        Loop
                Next
'
                w = ai(n) - alpa　　③
                ew = w/n　　④
                IF ew>=0 Then sg = 1 Else sg = -1　　⑤
                ew = abs(ew)　　⑥
                For i = 1 To n　　⑦
                        sewb = Int(ew*(i-1)+0.5)               '前の累加補正数
                        sewf = Int(ew*i+0.5)                       '後の累加補正数
                        et(i) = sg*(sewf - sewb)
                Next
                ai(1) = alpa + bt(1) - et(1)　　⑧
                Do While ai(1)>=1296000
                      ai(1) = ai(1) - 1296000
                Loop
                For i = 2 To n　　⑨
                        ai(i) = ai(i-1) + bt(i)- et(i) + 648000
                        Do While ai(i)>=1296000
                              ai(i) = ai(i) - 1296000
                        Loop
                Next
'
                ss = 0
                For i = 1 To n-1　　⑩
                        ss = ss + ds(i)
                Next
'
                dx(1) = Rund(ds(1)*cos(ai(1)/648000*PI),3)　　⑪
                dy(1) = Rund(ds(1)*sin(ai(1)/648000*PI),3)
                x(1) = xa + dx(1)
                y(1) = ya + dy(1)
                For i = 2 To n-1
                        dx(i) = Rund(ds(i)*cos(ai(i)/648000*PI),3)
                        dy(i) = Rund(ds(i)*sin(ai(i)/648000*PI),3)
                        x(i) = x(i-1) + dx(i)
                        y(i) = y(i-1) + dy(i)
                Next　　⑫
'
                sex = Rund(x(n-1) - xa,3)　　⑬
                sey = Rund(y(n-1) - ya,3)　　⑭
                exs = 0
                eys = 0
                ex(1) = Rund(sex*ds(1)/ss,3)　　⑮
                exs = exs + ex(1)
                ey(1) = Rund(sey*ds(1)/ss,3)
                eys = eys + ey(1)
                x(1) = xa + dx(1) - ex(1)
                y(1) = ya + dy(1) - ey(1)
                For i = 2 To n-2
                        ex(i) = Rund(sex*ds(i)/ss,3)
                        exs = exs + ex(i)
                        ey(i) = Rund(sey*ds(i)/ss,3)
                        eys = eys + ey(i)
                        x(i) = x(i-1) + dx(i) - ex(i)
                        y(i) = y(i-1) + dy(i) - ey(i)
                Next
                ex(n-1) = Rund(sex - exs,3)
                ey(n-1) = Rund(sey - eys,3)
                x(n-1) = x(n-2) + dx(n-1) - ex(n-1)
                y(n-1) = y(n-2) + dy(n-1) - ey(n-1)　　⑯
'
                delts=Rund(Sqr(sex^2 + sey^2),3)　　⑰
                IF delts<>0 Then
                      seido=Rund(ss/delts,0)　　⑱
                Else
                      seido=0
                End IF
                Heigo　　⑲
'
        End Sub

計算の中心になる部分です。

①②　　開放トラバースに追加したローカル変数です。このプロシージャの

中だけしか使わない変数ですから、プロシージャ内で宣言するローカル変数

にします。

③　　　　これより前の部分は、開放トラバースと同じです。閉合トラバースで

は、「終点の方向角と初点の方向角が同じ」という条件がありますので、その

差をとり測角誤差を求めます。

④　　　　１点当たりの測角誤差を求めています。

⑤⑥　　測角誤差の符号を取り、その絶対値を求めます。四捨五入しながら、

各点に配布する誤差（これを補正値といいます）を求めるので、プラスの値で

計算し後で元の符号に戻すようにしてあります。

⑦　　　　このループで各点に配布する補正値を求めます。その点までの累加

補正数から、１つ前までの累加補正数を減じて、その点に対する配布補正値

を求めます。

⑧⑨　　このループで、方向角を補正します。

⑩　　　　距離の合計を求めます。ss = 0 のように、まず合計する変数をクリ

アした方が安全です。

⑪～⑫　開放トラバースと同じで補正する前のＸＹ座標を求めます。

⑬⑭　　閉合トラバースでは、「終点の座標と初点の座標が同じ」という条件

がありますので、その差をとり閉合差を求めます。ここで、終点の番号は n-1

である点に注意してください。

⑮⑯　　各座標に対する補正値を計算しながら、補正した座標を求めます。

変数 exs と eys は、それぞれ最後のＸ座標とＹ座標の１つ前の点までの配

布量を合計する変数です。これを求めると、最後の点にのこりの補正値をす

べて配布できます。

⑰　　　　閉合差を求めます。

⑱　　　　精度の分母数を求めます。

⑲　　　　計算結果出力のプロシージャに飛びます。

Sub Heigo
　　・
　　・
　　・
End Sub

計算結果出力のプロシージャです。開放トラバースのプログラムに角度と座

標の補正値を追加しています。また、測角誤差、ΔＸ、ΔＹ、ΣＳ、閉合差、

精度を表示できるように、プログラムを追加してあります。

[もくじへ] [トップページへ]

　りょうかんのアドバイス

プログラミングが初めてという方には、閉合トラバースはちょっと難しくなりまし

たね。角度誤差とＸＹ座標誤差の補正を取り入れるだけで、こんなに複雑にな

りました。

「プログラムなんて、やーめた。りょうかんは、よくこんなに難しいプログラムが

作れるもんだ。おれには無理だ。」なんて言わないでくださいね。

実は、このプログラムを作るのに３日かかりました。ずぅーと考え続けて３日で

す。測点の番号と観測データとの関係がややっこしくて、何回も図を画いてみ

たり、プログラムを書き換えてみたり、そりゃー大変な無駄な？苦労をしたの

ですよ。最初からスラスラとできたのではないのです。

難しい数学の問題が解けなかったとき、参考書の似たような問題の解説を見

ますね。しかし、またその解説が分からなくてイライラするということがありませ

んでしたか。りょうかんのプログラムは、初めてプログラムを作る人にとって、

そんな参考書の解説のように見えるかもしれません。でも、そこであきらめたら

いけません。では、どうするか？　自分で、最初から作ってみるのです。動くよ

うになるまで。

一度自分の力で作ってしまうと、あとは面白くなってプログラム作りにはまるは

ずです。こんなに楽しいあそびがあったのかと・・・。がんばってくださいね。

さて、ここでプログラムを作る時、りょうかんが気を付けていることを２、３挙げた

いと思います。

１．データは、何回も入力するのはたいへんなので、最初は代入文にする。完

全に動くのを確めたら、入力フォームを接続する。

２．最初から何でも欲張らない。あれも、これもできるようにと欲を出すとプログ

ラミングの効率が悪くなる。

３．コメント（注釈）を多く入れる。後で見た時、分かるように。

４．いろんなデータでチェックする。面倒がらずに。

　　　・
　　　・
　　　・

次回は、『結合トラバース』の予定です。（１０月５日ごろ）

この講座に対する、ご意見やご要望はメールか掲示板・伝言板でお願

いします。

『VBScriptによる測量計算プログラミング入門』　

講師　大愚良寛

[もくじへ] [トップページへ] [次ページへ]